; Nauka Malowania (malowanie obrazow)
; v2010.9.19
;----------------------------------------------------------------
; Autor: Ictorn
; IRC: #tawerna, #IV (siec PolNet)
;================================================================
; Skrypt maluje obrazy i odklada je do plecaka glownego
; Po przekroczeniu ustawionej wagi zatrzymuje sie
; Moze jesc jesli potrzeba (patrz opis w ustawieniach)
;================================================================

; +------------+
; | USTAWIENIA |
; +------------+

; Czy jemy gdy jest potrzeba?
; Aby sprawdzanie/jedzenie dzialalo wymagany jest dodatkowy skrypt:
; http://iv.tawerna.net/skrypty/Inne/Jedzenie.txt
set %czyJesc #false
set %jedzenie QRD  ; TYP jedzenia
set %waga 800     ; maksymalna waga postaci

;================================================================
; +--------+
; | SKRYPT |
; +--------+

set %csize 540_420

finditem ZTI C_ , #BACKPACKID
if #FINDCNT > 0
{
    set %plotno #FINDID
}
else
{
    event sysmessage Brak plotna!
    halt
}
finditem FTF G_3
if #FINDCNT > 0
{
    set %sztaluga #FINDID
}
else
{
    event sysmessage Brak sztalugi!
    halt
}
finditem BXF C_ , #BACKPACKID
if #FINDCNT > 0
{
    set %paleta #FINDID
}
else
{
    event sysmessage Brak palety!
    halt
}

repeat
    if %czyJesc = #true
    {
        jesliGlod:
        if *ivGlod = #true
        {
            gosub jedzenie %jedzenie
            goto jesliGlod
        }
    }
    gosub waga %waga
    gosub maluj
until #false

halt

sub maluj
    set #lobjectid %plotno
    event macro 17 0

    repeat
    until #targcurs = 1

    set #ltargetid %sztaluga
    set #ltargetkind 1
    event macro 22

    wait 20

    set #lobjectid %paleta
    event macro 17 0

    repeat
    until #contsize = %csize

    click 510 60

    set %ji #jindex
    set %ok #false

    repeat
       if %ji < #jindex
    {
        set %ji %ji + 1
             scanjournal %ji

        if ( Namalowal in #journal && obraz in #journal ) || Nie_udalo_Ci_sie in #journal
        {
            set %ok #true
        }
    }
    until %ok
return

sub waga
    if %0 <> 1
        return

    if #WEIGHT > %1
    {
        event sysmessage Przekroczono dopuszczalna wage! Koniec skryptu.
        halt
    }
return

sub jedzenie
    finditem %1 C
    if #FINDCNT > 0
    {
        set #lobjectid #FINDID
        event macro 17
    }
    else
    {
        event sysmessage SKONCZYLO SIE JEDZENIE!
        halt
    }

    wait 2s
return