; ======================
; Kox traperstwa by urug
; Konfiguracja (1=on/0=off)
set %ukrywaj_sie 0 ; Koxac trape na hidzie?
set %jedz 1        ; Czy postac ma jesc?
; ======================

gosub reset
while ( #clilogged = 1 )
{
      gosub read_journal
      gosub trapka
      gosub timeout

      if ( %startuj = 0 )
      {
           gosub jedz
           gosub ukryj_sie
           gosub print_gain
      }
}


; ======================
; Resetuj wszystkie zmienne
; ======================
sub reset
{
    ; gainy
    set %licz 0
    set %licz_gain 0
    set %time_gain NIEZNANY
    set %print_gain 0
    ; tropienie
    set %startuj 0
    set %tropie 0
    set %nic_nie_odczytales 0
    ; inne
    set %jestes_glodny 0
    set %jindex #jindex

    return
}


; ======================
; Trapka
; ======================
sub trapka
{
    if ( %startuj = 0 )
    {
         event macro 1 0 .um traperstwo
         set %startuj 1
         set %time_start #SCNT
    }
    else
    {
        ; Kliknij w 'stworzenia'
        while ( #CONTSIZE = 190_220 && #CONTNAME = generic_gump )
              click 78 90

        ; W  kolejnym okienku kliknij pierwsza z gory istote
        while ( #CONTSIZE = 380_460 && #CONTNAME = generic_gump )
        {
              click 88 100
              wait
              if ( ! ( #CONTSIZE = 380_460 && #CONTNAME = generic_gump ) )
              {
                   set %tropie 1
                   set %licz %licz + 1
              }
        }

        if ( %tropie = 1 )
        {
             set %startuj 0
             set %tropie 0
             wait 8s
             return
        }

        if ( %nic_nie_odczytales = 1 )
        {
             set %startuj 0
             set %nic_nie_odczytales 0
             wait 9s
             return
        }
    }

    return
}


; ======================
; Modyfikuj zmienne na podstawie zawartosci journala
; ======================
sub read_journal
{
      set %last #jindex
      while ( %jindex <= %last )
      {
            scanjournal %jindex
            set %jindex %jindex + 1

            if ( Odrobine_zglodniales. in #journal )
            {
                 set %jestes_glodny 1
                 continue
            }

            if ( Nie_odczytales_nic_ze_sladow_na_ziemi. in #journal )
            {
                 set %nic_nie_odczytales 1
                 continue
            }

            if ( Your_skill_in_Traperstwo_has_increased_by_ in #journal )
            {
                 set %licz_gain %licz + 1
                 set %licz 0

                 set %old_time %time_gain
                 set %time_gain #TIME
                 str Ins %time_gain : 3
                 set %time_gain #strres
                 str Ins %time_gain : 6
                 set %time_gain #strres

                 event sysmessage Gain po: %licz_gain skutecznych uzyciach umiejetnosci, godzina: %time_gain ( Wczesniejszy o %old_time )
                 continue
            }
     }

     return
}


; ======================
; Nie pozwol zablokowac sie skryptowy
; ======================
sub timeout
{
    if ( %startuj = 1 && ( #SCNT - %time_start ) > 25 )
    {
         event sysmessage TIMEOUT
         set %startuj 0
    }

    return
}


; ======================
; Wyswietl czas ostatniego gaina
; ======================
sub print_gain
{
    if ( %print_gain = 5 )
    {
         event sysmessage Skuteczne uzycia umiejetnosci: %licz ( na %licz_gain potrzebnych do gaina )
         set %print_gain 0
    }
    else
         set %print_gain %print_gain + 1

    return
}


; ======================
; Ukryj sie
; ======================
sub ukryj_sie
{
    if ( %ukrywaj_sie = 1 && H notin #charstatus )
    {
         event macro 1 0 .um ukrywanie
         wait 10s
    }

    return
}


; ======================
; Jedz ktores z dostepnych typow zarcia
; ======================
sub jedz
{
    if ( %jedz = 0 || %jestes_glodny = 0  )
         return
    else
         set %jestes_glodny 0

    finditem QRD_HQD_NRD C
    if ( #findkind = -1 )
    {
         event sysmessage Brak znanych typow jedzenia, nie bede jadl.
         return
    }

    set %tmp #lobjectid
    set #lobjectid #findid
    event macro 17
    set #lobjectid %tmp
    wait 1s

    return
}